#!/bin/csh -f
#
#########################################################################
#
# This script generates a batch job script that can be fed into
# PBS  as in:  qsub created_script
#
# arg1 job name
# arg2 maximum number of events to process
# arg3 job number
#
#########################################################################
#
setenv ARG1 $1
setenv ARG2 $2
setenv ARG3 $3
setenv ARG4 $4
set FIRSTEVENT = 0
@ FIRSTEVENT = ${ARG2} * (${ARG3} - 1)

set RANDOM = 0
@ RANDOM = ${FIRSTEVENT} + 123456789

# number of events to process per file (-1 = all)
setenv MAXEVENTS ${ARG2}

setenv basename ${ARG1}_${ARG3}
setenv fname ${basename}.job

echo Job file will be ${fname}

cat - > ${fname} <<EOF
#!/bin/csh -f
# PBS parameters
#
#PBS -q cms_analysis@hamlet
#PBS -N ${basename}
#PBS -l walltime=34:00:00
# Send me an email on  a=abort, b=begin, e=end
##PBS -m e
##PBS -M xu2@purdue.edu
#PBS -o /scratch/osg/cmssw/xu2/CMSSW_1_0_6/src/${basename}.log
# Merge standard output and error streams 
#PBS -j oe
# declare job non-rerunable
#PBS -r n  
#PBS -V
#
# ---------------------------------------------------------
#
set nonomatch

echo ""
echo "Job is running on \`uname -a\`"
if ( \${OSTYPE} == "linux" ) then
  set processor = \`sort /proc/cpuinfo | uniq | gawk -F: '(substr(\$1,1,10)=="model name"){print \$2}'\`
  set rate = \`sort /proc/cpuinfo | uniq | gawk -F: '(substr(\$1,1,7)=="cpu MHz"){print substr(\$2,1,6)}'\`
  echo "Processor info : " \$processor \$rate "MHz"
endif
set start = \`date\`
echo "Job started on \`date\`"
echo ""

echo ------------------------------------------------------
echo PBS: qsub is running on \$PBS_O_HOST
echo PBS: originating queue is \$PBS_O_QUEUE
echo PBS: executing queue is \$PBS_QUEUE
echo PBS: working directory is \$PBS_O_WORKDIR
echo PBS: execution mode is \$PBS_ENVIRONMENT
echo PBS: job identifier is \$PBS_JOBID
echo PBS: job name is \$PBS_JOBNAME
echo PBS: current home directory is \$PBS_O_HOME
#echo PBS: PATH = \$PBS_O_PATH
echo ------------------------------------------------------

#
#----------------------------------------------------------
# s e t   t h e   r u n t i m e   e n v i r o n m e n t
#----------------------------------------------------------
#
source /apps/02/purdueCMS/cmsset_default.csh
#source /apps/02/cmssoft/cms/setup/group_env_CMS.csh
#source /opt/osg/setup.csh  #need not because otherwise it will point to different perl lib

setenv X509_USER_PROXY \${HOME}/gridcert

setenv CMSSW_RELEASE CMSSW_1_0_6
setenv SCRAM_ARCH slc3_ia32_gcc323 

#setenv CMS_PATH /afs/cern.ch/cms
setenv SRCDIR   /scratch/osg/cmssw/xu2/\${CMSSW_RELEASE}
setenv OUTDIR   /scratch/osg/cmssw/xu2/output
setenv WORKDIR  /tmp/PBS_\${PBS_JOBID}
#setenv PATH /scratch/osg/xu2_perl/local/bin:$PATH
echo " "
echo "Output directory is : " \$OUTDIR
echo " "

#
#----------------------------------------------------------
# s e t   t h e   r u n t i m e   e n v i r o n m e n t
#----------------------------------------------------------
#

cd \${SRCDIR}/src
eval \`scramv1 runtime -csh\` 

#
#----------------------------------------------------------
# c o p y   e x e   a n d   c o n f i g    f i l e s
#----------------------------------------------------------
#

mkdir \${WORKDIR}
cd \${WORKDIR}

#
#----------------------------------------------------------
# set CMSSW environment
#----------------------------------------------------------
#
/bin/rm -f job.cfg
cat > job.cfg <<@EOF
`cat ${ARG4}`
@EOF
#
#----------------------------------------------------------
# e x e c u t e   j o b
#----------------------------------------------------------
#

 echo "Processing Event Collection : $basename  " 

 /usr/bin/time -f "%e %U %S %x" -o x cmsRun -p job.cfg

 set rtime = \`tail -1 x | cut -f 1 -d " "\`
 set utime = \`tail -1 x | cut -f 2 -d " "\`
 set stime = \`tail -1 x | cut -f 3 -d " "\`
 set stat  = \`tail -1 x | cut -f 4 -d " "\`

#
#----------------------------------------------------------
# c o p y   o u t p u t
#----------------------------------------------------------
#
#  if ( \${status} != 0 ) cp \${WORKDIR}/*.root \${OUTDIR}/${basename}.root
    cp \${WORKDIR}/*.root \${OUTDIR}/${basename}.root
   
#
# show what is being left behind...
#
  echo ""
  echo "Current directory:"
  pwd
  ls -lrtAFh
#
  set end = \`date\`
  echo ""
  echo "Job end \`date\`"
  echo ""
#
echo \$PBS_JOBNAME \$stat \$start \$end \`uname -n | cut -f 1 -d .\` \$processor \$rate \$rtime \$utime \$stime  >> \${OUTDIR}/SUMMARY
#
rm -r \${WORKDIR}
exit \${status}
EOF

chmod +x ${fname}